StateManager

/*
Manages the states of the application
@author Martijn de Visser
*/

// framework classes
import org.asapframework.util.debug.Console;
import org.asapframework.events.Dispatcher;
import org.asapframework.events.Event;

// playground classes
import management.StateManagerEvent;

class management.StateManager extends Dispatcher {
    
    private var mCurrentState:String = null;
    private var mRequestedState:String;
    private var mChangingState:Boolean = false;
    private static var sInstance:StateManager = null;
    
    /**-----------------------------------------------------------------------
    Private constructor, use getInstance to refer to singleton instance.
    -------------------------------------------------------------------------*/
    private function StateManager () {
        super();
    }
    
    /**-------------------------------------------------------------------------
    Returns reference to singleton instance of StateManager.
    --------------------------------------------------------------------------*/
    public static function getInstance () : StateManager {
        if (StateManager.sInstance == null) {
            StateManager.sInstance = new StateManager();
        }
        return sInstance;
    }
    
    /**-------------------------------------------------------------------------
    Sets the new state. Calls {@link #unLoadState} if the current state is not unloaded yet; otherwise calls {@link #loadState}. 
    @param inStateName : the new state identifier
    @example
    This example sets the state to 'home':
    <code>
    StateManager.getInstance().setState(AppSettings.HOME_NAME);
    </code>
    --------------------------------------------------------------------------*/
    public function setState (inStateName:String) : Void {
        // handle only if we're not already changing state and different state is requested
        if (!mChangingState && (inStateName != mCurrentState)) {
            if (mCurrentState == null) {
                // load now
                loadState(inStateName);
            } else {
                // unload first
                unLoadState(inStateName);
            }
        }
    }
    
    /**-------------------------------------------------------------------------
    To be called when unloading a movie has been successful. Continues to the next state, unless state change is already taking place.
    @example
    <code>
    if (movieManager.removeMovie(inMovieName)) {
        StateManager.getInstance().unloadDone();
    }
    </code>
    --------------------------------------------------------------------------*/
    public function unloadDone () : Void {
        if (!mChangingState) {
            loadState(mRequestedState);
        }
    }
    
    /**-------------------------------------------------------------------------
    The current state.
    --------------------------------------------------------------------------*/
    public function get state () : String {
    
        return mCurrentState;
    }
    
    /**-------------------------------------------------------------------------

    --------------------------------------------------------------------------*/
    public function toString () : String {
        return "; management.StateManager";
    }
    
    // PRIVATE METHODS
    
    /**-----------------------------------------------------------------------
    Starts the unloading of the current state.
    @param inState : the identifier of the state to unload
    @sends StateManagerEvent#UNLOAD_START
    -------------------------------------------------------------------------*/
    private function unLoadState ( inState:String ) : Void {
    
        // store requested state
        mRequestedState = inState;

        // notify loaded movie to unload
        dispatchEvent( new StateManagerEvent( StateManagerEvent.UNLOAD_START, this, mCurrentState, mRequestedState));
    }

    /**-----------------------------------------------------------------------
    Starts the loading of the requested state.
    @param inState : the identifier of the state to load
    @sends StateManagerEvent#LOAD_START
    -------------------------------------------------------------------------*/
    private function loadState ( inState:String ) : Void {
            
        // set current state
        mCurrentState = inState;
            
        // notify loaded movie to unload
        dispatchEvent(new StateManagerEvent(StateManagerEvent.LOAD_START, this, mCurrentState, mCurrentState));
    }
    
    
}