ButtonBackground

/*
Copyright 2005-2006 by the authors of asapframework, http://asapframework.org

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

       http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*/

/**
Button background class with 3 part clips: center, left and right. By setting the width of the center clip, the side clips positions are automatically adjusted.

The 3 ButtonBackground movieclips are: <code>center_mc</code>, <code>left_mc</code> and <code>right_mc</code>.
@author Arthur Clemens
@version 4 Feb 2006
@use
In a (custom, centered) button class:
<code>
    private var label_tf:TextField;
    private var background_mc:ButtonBackground;
    private var BUTTON_WIDTH_OFFSET:Number = 5;

    // ...
    
    public function setLabel (inText:String) : Void {
        // put the label text in the text field
        label_tf.text = inText;
        // calculate the new width of the text field, and add an amount to account for Flash cutting off chars at the end
        var width:Number = label_tf.textWidth * 1.15;
        // set the text frame width to its contents
        label_tf._width = width;
        // set the width of the background
        background_mc.setWidth(width, BUTTON_WIDTH_OFFSET);
        
        // center the label
        label_tf._x = -width/2;
        // center the background
        background_mc._x = -background_mc._width/2;
    }
</code>
For a left-aligned button:
<code>
    public function setLabel (inText:String) : Void {
        // put the label text in the text field
        label_tf.text = inText;
        // calculate the new width of the text field, and add an amount to account for Flash cutting off chars at the end
        var width:Number = label_tf.textWidth * 1.15;
        // set the text frame width to its contents
        label_tf._width = width;
        // set the width of the background
        background_mc.setWidth(width, BUTTON_WIDTH_OFFSET);
        
        // left-align the label
        label_tf._x = background_mc.getCenterClipPosition() + BUTTON_WIDTH_OFFSET;
        // left-align the background
        background_mc._x = 0;
    }
</code>
*/

class playground.classes.ui.buttons.ButtonBackground extends MovieClip {

    private var center_mc:MovieClip; /**< The center background clip; usually the button label will be positioned in the middle of the center clip, one or more layers higher. The center clip will be stretched to fit the button width in {@link #setWidth}. */
    private var left_mc:MovieClip; /**< The left background clip. */
    private var right_mc:MovieClip; /**< The right background clip; usually this will be the left clip symbol mirrored. */
    private var mOffset:Number;
    
    /**
    Sets the width of the center clip, plus (optionally) a side offset. This offset will be added to the two sides of the center clip.
    @param inWidth : the width of the center clip
    @param inOffset : the width of the side offset
    */
    public function setWidth (inWidth:Number, inOffset:Number) : Void {
        mOffset = inOffset;
        var offset:Number = (inOffset != undefined) ? inOffset : 0;
        center_mc._width = inWidth + (2 * inOffset);
        left_mc._x = 0;
        center_mc._x = left_mc._width;
        right_mc._x = center_mc._x + center_mc._width;
     }
     
     /**
     The position of the center clip.
     */
     public function getCenterClipPosition () : Number {
         return center_mc._x;
     }
     
}