MenuController

import org.asapframework.data.array.ArrayEnumerator;
import org.asapframework.management.movie.LocalController;
import org.asapframework.ui.buttons.EventButtonEvent;

import data.ProjectData;

import events.ProjectButtonEvent;
import events.ProjectEvent;

import ui.ProjectButton;

/**
controllers.MenuController handles ProjectButton events and passes them to event listeners (AppController).
*/

class controllers.MenuController extends LocalController {
    
    private static var MENU_BUTTONS_STACK_DEPTH = 10;
    private static var PADDING_LEFT:Number = 12;
    private static var BUTTON_HEIGHT:Number = 36;
    
    /**
    The project id of the selected menu item.
    */
    private var mSelectedProjectId:String = null;
    /**
    Quick lookup reference of the button that belongs to a project id.
    */
    private var mProjectIdToButtonHash:Object = new Object();
    
    /**
    Creates a new controllers.MenuController with mTimeline <code>inTimeline</code>.
    */
    public function MenuController (inTimeline:MovieClip) {
        super(inTimeline);
    }
        
    /**
    Creates buttons of type {@link ProjectButton}.
    */
    public function createButtons (inProjectData:Array) : Void {
        var e:ArrayEnumerator = new ArrayEnumerator(inProjectData);
        var project:ProjectData = null;
        var count:Number = 0;
        while (project = e.getNextObject()) {
            var btn:ProjectButton = ProjectButton(mTimeline.attachMovie("project_button", "btn_" + count, MENU_BUTTONS_STACK_DEPTH + count));
            btn._x = PADDING_LEFT;
            btn._y = BUTTON_HEIGHT * count;
            btn.setProjectLabel(project.name);
            btn.setClientLabel(project.client);
            btn.setId(project.id);
            var isValidUrl:Boolean = project.url != undefined && project.url != null && project.url != "";
            if (isValidUrl) {
                btn.setHasWebsite(true);
                btn.addEventListener(ProjectButtonEvent.WEB_BUTTON_HIT, this);
            }
            mProjectIdToButtonHash[project.id] = btn;
            count++;
        }
    }
    
    /**
    Updates the menu to a given state.
    @param inProjectId : the name of the new state
    */
    public function setSelectedProject (inProjectId:String) : Void {
        var selectedButton:ProjectButton = mProjectIdToButtonHash[mSelectedProjectId];
        if (selectedButton) {
            selectedButton.deselect();
        }
        var newButton:ProjectButton = mProjectIdToButtonHash[inProjectId];
        if (newButton) {
            newButton.select();
        }
        mSelectedProjectId = inProjectId;
    }
    
    // PRIVATE METHODS

    // EVENTS
    
    /**
    Passed by {@link ProjectButton} rollover.
    */
    private function onEventButtonRollOver ( e:EventButtonEvent ) : Void {
        var projectId:String = ProjectButton(e.target).getId();
        dispatchEvent(new ProjectEvent(ProjectEvent.PROJECT_SHOW, this, projectId));
    }

    /**
    Passed by {@link ProjectButton} rollout.
    */
    private function onEventButtonRollOut ( e:EventButtonEvent ) : Void {
        var projectId:String = ProjectButton(e.target).getId();
        dispatchEvent(new ProjectEvent(ProjectEvent.PROJECT_HIDE, this, projectId));
    }
    
    /**
    Passed by {@link ProjectButton} release.
    */
    private function onEventButtonRelease ( e:EventButtonEvent ) : Void {
        var projectId:String = ProjectButton(e.target).getId();
        dispatchEvent(new ProjectEvent(ProjectEvent.PROJECT_SELECT, this, projectId));
    }

    /**
    Passed by {@link ProjectButton} when the web button is released.
    */
    private function onWebButtonHit (e:ProjectButtonEvent) : Void {
        var projectId:String = ProjectButton(e.target).getId();
        dispatchEvent(new ProjectEvent(ProjectEvent.PROJECT_VISITSITE, this, projectId));
    }
    
}