BWAMovieClipUtils

/*
Copyright 2005-2006 by the authors of asapframework, http://asapframework.org

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

       http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*/

import flash.display.BitmapData;

class util.BWAMovieClipUtils {

    /**
    Smoothes the image of a MovieClip, by copying the image bitmap data to a new MovieClip.
    @param inClip : the MovieClip to smooth the image of
    @return A new MovieClip with the smoothed bitmap data of the original clip.
    @usageNote If the passed clip <code>inClip</code> is a class member, the reference to the original member will be lost. For instance
    <code>
    private var clip_mc:MovieClip;
    // after smoothing:
    clip_mc._x = 100; // does not work
    </code>
    The solution is to make the member reference dynamic:
    <code>
    private var mImageClip:MovieClip;
    
    // Sets the reference to the image clip after smoothing so Image knows which clip to handle.
    public function setImageClip (inClip:MovieClip) : Void {
        mImageClip = inClip;
    }
    // after smoothing:
    mImageClip._x = 100;
    </code>
    @example
    To use <code>smoothMovieClip</code> with <code>Loader</code>
    <code>
    private function onLoadDone (e:LoaderEvent) : Void {
        var clip:MovieClip = MovieClip(e.targetClip);
        var smoothedClip:MovieClip = util.BWAMovieClipUtils.smoothMovieClip(clip);
    }
    </code>
    To set the smoothed image clip reference dynamically, add:
    <code>
        // tell parent image to use the new smoothed clip
        var parent:MovieClip = smoothedClip._parent;
        parent.setImageClip(smoothedClip);
    </code>
    In the parent class, write:
    <code>
    public function setImageClip (inClip:MovieClip) : Void {
        mImageClip = inClip;
    }
    </code>
    */
    public static function smoothMovieClip (inClip:MovieClip) : MovieClip {
    
        var parent:MovieClip = inClip._parent;
        var name:String = inClip._name;
        var depth:Number = inClip.getDepth();
        var width:Number = inClip._width;
        var height:Number = inClip._height;
        
        // Create new BitMap data object and draw the loaded bitmap
        // in the new bitmap
        var bitmap:BitmapData = new BitmapData(width, height, true, 0x000000);
        bitmap.draw(inClip);
        
        // remove original bitmap
        inClip.unloadMovie();
        inClip.removeMovieClip();
        delete inClip;
        
        // Create a new movieclip to display the bitmap with
        var smoothClip:MovieClip = parent.createEmptyMovieClip(name + "_smoothed", parent.getNextHighestDepth());
        smoothClip.swapDepths(depth);

        // Draw the BitMap in the new clip, using the 'smoothing' flag
        smoothClip.attachBitmap(bitmap, smoothClip.getNextHighestDepth(), "auto", true);
        
        return smoothClip;
    }
}