MyLocalController

// ASAP classes
import org.asapframework.management.movie.*;
import org.asapframework.util.actionqueue.*;

// project classes
import events.MyLocalControllerEvent;

/**
Provides shared functionality for all loaded movies (home and gallery).
1) the fading in of the movies in {@link #show}.
2) the fading out of the movies in {@link #hide}.
*/

class controllers.MyLocalController extends LocalController {

    private static var FADE_DURATION:Number = .3;
    
    /**
    
    */
    public static function main (inTimeline:MovieClip) : Void {
        // create new controller
        var controller:MyLocalController = new MyLocalController(inTimeline);
        // store controller on mTimeline
        inTimeline.localController = controller;
    }
    
    /**
    
    */
    function MyLocalController (inTimeline:MovieClip) {
        super(inTimeline);
        // let MovieManager know initialization is done
        notifyMovieInitialized();
    }
    
    /**
    Overriding LocalController's show to let the movies fade in.
    */
    public function show () : Void {
        // prepare for fade in
        mTimeline._visible = true;
        mTimeline._alpha = 0;
        // fade in
        var queue:ActionQueue = new ActionQueue();
        queue.addAction( AQFade.fade, mTimeline, FADE_DURATION, 0, 100 );
        queue.run();
    }
    
    /**
    Overriding LocalController's hide to let the movies fade out.
    */
    public function hide () : Void {
        var queue:ActionQueue = new ActionQueue();
        queue.addAction( AQFade.fade, mTimeline, FADE_DURATION, null, 0 );
        queue.addAction( AQSet.setVisible, mTimeline, false);
        queue.addAction( this, this.dispatchEvent, new MyLocalControllerEvent(MyLocalControllerEvent.ON_OUTANIMATIONDONE, this) );
        queue.run();
    }
        
}