MyController

import org.asapframework.management.movie.LocalController;
import org.asapframework.ui.buttons.EventButtonEvent;
import ui.ClickButton;

/**
This demo accompanies the HowTo "How to create a new Flash application with the ASAP Framework" on asapframework.org:
http://asapframework.org/wiki/bin/view/ASAP/CreateABasicApplication
@author Martijn de Visser
*/
 
class controllers.MyController extends LocalController {
    
    /**
    A reference to an element on the stage.
    */
    private var myTextField:TextField;
    
    /**
    A button on the stage.
    */
    private var myButton:ClickButton;
    
    /**
    Private constructor (called through .main entry point).
    */
    private function MyController ( inTimeline:MovieClip ) {
    
        // always call super!
        super(inTimeline);
    }
    
    /**
    The "main" entry point.
    @usage You call this method from the mTimeline to instantiate your controller like this:
    <code>
    import controllers.MyController;
    MyController.main(this);
    </code>
    */
    public static function main ( inTimeline:MovieClip ) : Void {
        
        // create an instance of MyController...
        var controller:MyController = new MyController(inTimeline);
        
        // ...place a reference to the controller in the main mTimeline...
        inTimeline.controller = controller;
        
        // .. and start it
        controller.start();
    }
    
    /**
    The 'start' function is called in the {@link #main} entry point.
    */
    public function start () : Void {

        // the 'mTimeline' property references to the main
        // mTimeline fo the SWF we're controlling.
         
        // stop the mTimeline from playing (in case an animation is going on)
        mTimeline.stop();
        
        // set reference to textfield
        myTextField = TextField(mTimeline.feedback_txt);
        
        // now we can set the text in this textfield:
        myTextField.text = this + " has started";
        
        showFeedback("myTextField = " + myTextField);
        
        // set reference to button in stage. Note that this
        // button is based on EventButton, so it will automatically
        // fire the 'onEventButtonRelease' event to our Controller class
        myButton = ClickButton(mTimeline.myButton);
        
        // if you want to catch additional events coming from an
        // EventButton-based button, you can enable them like this:
        myButton.setSendEventOnRoll(true);
        myButton.setSendEventOnPress(true);
        
        showFeedback("myButton = " + myButton);
    }
    
    /**
    This event is automatically fired by all buttons based on EventButton.
    */
    public function onEventButtonRelease ( e:EventButtonEvent ) : Void {

        showFeedback(e.buttonName + ": released");
    }
    
    /**
    This event is automatically fired by all buttons based on EventButton if <code>setSendEventOnPress</code> has been set to 'true': <code>myButton.setSendEventOnPress(true)</code>;
    */
    public function onEventButtonPress ( e:EventButtonEvent ) : Void {

        showFeedback(e.buttonName + ": pressed");
    }
    
    /**
    This event is automatically fired by all buttons based on EventButton if <code>setSendEventOnRoll</code> has been set to 'true': <code>myButton.setSendEventOnRoll(true);</code>
    */
    public function onEventButtonRollOver ( e:EventButtonEvent ) : Void {

        showFeedback(e.buttonName + ": rollover");
    }
    
    /**
    This event is automatically fired by all buttons based on EventButton if <code>setSendEventOnRoll</code> has been set to 'true': <code>myButton.setSendEventOnRoll(true);</code>
    */
    public function onEventButtonRollOut ( e:EventButtonEvent ) : Void {

        showFeedback(e.buttonName + ": rollout");
    }
    
    /**
    Shows the class name.
    */
    public function toString() : String {
        
        return "controllers.MyController";
    }
    
    // PRIVATE METHODS
    
    /**
    
    */
    private function showFeedback ( inText:String ) : Void {
    
        myTextField.text += "\n" + inText;
        myTextField.scroll = myTextField.maxscroll;
    }
    
}